[Setup]
AppID={code:GetAppID|''}
AppName=AgileTrack
AppVerName=AgileTrack {code:GetAppMajorVersion|''}{code:GetAppMinorVersion|''} build {code:GetAppCurrentVersion|''}
AppPublisher=Adam Lane
AppPublisherURL=http://agiletrack.org
AppSupportURL=http://agiletrack.org
AppUpdatesURL=http://agiletrack.org
DefaultDirName={pf}\AgileTrack
DefaultGroupName=AgileTrack
AllowNoIcons=yes
OutputDir=dist
OutputBaseFilename=agiletrack-setup
Compression=lzma
SolidCompression=yes
InfoBeforeFile=doc\readme.rtf

[Languages]
Name: eng; MessagesFile: compiler:Default.isl

[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked
Name: quicklaunchicon; Description: {cm:CreateQuickLaunchIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked

[Files]
Source: dist\client\agiletrack-windows\agiletrack.exe; DestDir: {app}; Flags: ignoreversion
Source: dist\client\agiletrack-windows\*; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs
; NOTE: Don't use "Flags: ignoreversion" on any shared system files
Source: major.dat; DestDir: {tmp}; Flags: dontcopy
Source: minor.dat; DestDir: {tmp}; Flags: dontcopy
Source: build.dat; DestDir: {tmp}; Flags: dontcopy

[INI]
Filename: {app}\agiletrack.url; Section: InternetShortcut; Key: URL; String: http://agiletrack.org

[Icons]
Name: {group}\AgileTrack; Filename: {app}\agiletrack.exe; WorkingDir: "{app}"
Name: {group}\{cm:ProgramOnTheWeb,agiletrack.org}; Filename: {app}\agiletrack.url
Name: {userdesktop}\AgileTrack; Filename: {app}\agiletrack.exe; Tasks: desktopicon; WorkingDir: "{app}"
Name: {userappdata}\Microsoft\Internet Explorer\Quick Launch\AgileTrack; Filename: {app}\agiletrack.exe; Tasks: quicklaunchicon; WorkingDir: "{app}"
Name: {group}\{cm:UninstallProgram,AgileTrack}; Filename: "{uninstallexe}"

[Run]
Filename: {app}\agiletrack.exe; Description: {cm:LaunchProgram,AgileTrack}; Flags: nowait postinstall skipifsilent

[UninstallDelete]
Type: files; Name: {app}\agiletrack.url

[Registry]
Root: HKLM; Subkey: Software\AgileTrack; ValueType: string; ValueName: Version; ValueData: {code:GetAppMajorVersion|''}; Flags: uninsdeletekey
Root: HKLM; Subkey: Software\AgileTrack; ValueType: string; ValueName: CurrentVersion; ValueData: {code:GetAppCurrentVersion|''}; Flags: uninsdeletekey

[Code]
function GetAppMajorVersion(param: String): String;
	var
		AppVersion: String;
	begin
		ExtractTemporaryFile('major.dat');
		LoadStringFromFile(ExpandConstant('{tmp}\major.dat'), AppVersion);
		Result := AppVersion;
	end;

function GetAppMinorVersion(param: String): String;
	var
		AppMinorVersion: String;
	begin
		ExtractTemporaryFile('minor.dat');
		LoadStringFromFile(ExpandConstant('{tmp}\minor.dat'), AppMinorVersion);
		Result := AppMinorVersion;
	end;
	
function GetAppCurrentVersion(param: String): String;
	var
		BuildVersion: String;
	begin
		ExtractTemporaryFile('build.dat');
		LoadStringFromFile(ExpandConstant('{tmp}\build.dat'), BuildVersion);
		Result := BuildVersion;
	end;

function GetAppID(param: String): String;
	begin
		Result := 'AgileTrack';
	end;